Domain-Oriented Reduction of Rule-Based Network Models
From BioNetWiki
N. M. Borisov, A. S. Chistopolsky, J. R. Faeder, and B. N. Kholodenko. Domain-Oriented Reduction of Rule-Based Network models. Submitted to IET Systems Biology.
- Preprint
- Supplementary material
- A macro-enabled version is available from BioNetGen Distributions. You must download version 2.0.47alpha to use the macro module. The macro module does not work in Version 2.0.48. We hope to correct this problem in the near future.
Contents |
[edit]
Using the Macro Module
[edit]
Basic Usage
In the Perl2 directory of the distribution, there is a file called MacroBNG2.pl, which is a replacement driver for BioNetGen that can be used to access the Macro module. The basic usage is
<path-to-BNG>/Perl2/MacroBNG2.pl [options] file.bngl
Two main options are used to access and control the Macro module.
MacroBNG2.pl --macro file.bngl
uses the Macro module to generate any network using the generate_network command. It will find and apply all reductions using the algorithm described in the preprint above.
MacroBNG2.pl --macro --nored A,B file.bngl
performs Macro reduction on the model in file.bngl omitting proteins A and B.
[edit]
Examples
Reducible network models from the Preprint Supplements.
[edit]
EGFR-like model
begin parameters
# Total concentrations
L_tot 100
R_tot 100
A_tot 100
B_tot 100
# Kinetic constants
k1 0.003
k_1 0.18
k2 0.01
k_2 3.0
k3 0.6
k_3 0.4
k4 0.4
k_4 0.6
k5 0.03
k_5 1
k6 0.03
k_6 1
k7 0.3
k_7 0.7
k8 0.7
k_8 0.3
end parameters
begin species
L(r) L_tot # Ligand
R(r1,r2,r3~Y,r4~Y) R_tot # Receptor
# r1 on R is the ligand-binding site
# r2 on R is the dimerization site
# r3 on R is the tyrosine residue for binding the adapter A
# r4 on R is the tyrosine residue for binding the adapter B
A(r) A_tot # Non-scaffolding adaptor
B(b1,b2~Y,b3~Y) B_tot # Scaffolding adaptor
end species
begin reaction_rules
L(r) + R(r1) <-> L(r!1).R(r1!1) k1, k_1 # Ligand binding
L(r!1).R(r1!1,r2) + L(r!2).R(r1!2,r2) <-> \
L(r!1).R(r1!1,r2!3).L(r!2).R(r1!2,r2!3) k2, k_2 # Dimerization
R(r2!+,r3~Y) -> R(r2!+,r3~pY) k3 # Receptor phosphorylation at site r3
R(r3~pY) -> R(r3~Y) k_3 # Receptor dephosphorylation at site r3
R(r2!+,r4~Y) -> R(r2!+,r4~pY) k4 # Receptor phosphorylation at site r4
R(r4~pY) -> R(r4~Y) k_4 # Receptor dephosphorylation at site r4
R(r3~pY) + A(r) <-> R(r3~pY!1).A(r!1) k5, k_5 # Binding adapter A
R(r4~pY) + B(b1) <-> R(r4~pY!1).B(b1!1) k6, k_6 # Binding adapter B
B(b1!+,b2~Y) -> B(b1!+,b2~pY) k7 # Adaptor B phosphorylation at site b2
B(b2~pY) -> B(b2~Y) k_7 # Adaptor B dephosphorylation at site b2
B(b1!+,b3~Y) -> B(b1!+,b3~pY) k8 # Adaptor B phosphorylation at site b3
B(b3~pY) -> B(b3~Y) k_8 # Adaptor B dephosphorylation at site b3
end reaction_rules
begin observables
Molecules L_tot L
Molecules R_tot R
Molecules A_tot A
Molecules B_tot B
Molecules R_dim R.R
Molecules Abound A(r!+)
Molecules B1pY B(b2~pY)
Molecules B2pY B(b3~pY)
end observables
generate_network({overwrite=>1});
simulate_ode({t_end=>40,n_steps=>40,atol=>1e-8,rtol=>1e-8,sparse=>1});
[edit]
FceRI-like model
begin parameters
# Total concentrations
L_tot 100
R_tot 100
A_tot 100
B_tot 100
# Kinetic constants
k1 0.003
k_1 0.18
k2 0.01
k_2 3.0
k3 0.6
k_3 0.4
k4 0.4
k_4 0.6
k5 0.03
k_5 1
k6 0.03
k_6 1
k7 0.3
k_7 0.7
k8 0.7
k_8 0.3
end parameters
begin species
L(r) L_tot # Ligand
R(r1,r2,r3~Y,r4~Y) R_tot # Receptor
# r1 on R is the ligand-binding site
# r2 on R is the dimerization site
# r3 on R is the tyrosine residue for binding the adaptor A
# r4 on R is the tyrosine residue for binding the adaptor B
A(r) A_tot # Non-scaffolding adaptor
B(b1,b2~Y,b3~Y) B_tot # Scaffolding adaptor
end species
begin reaction_rules
L(r) + R(r1) <-> L(r!1).R(r1!1) k1, k_1 # Ligand binding
L(r!1).R(r1!1,r2) + L(r!2).R(r1!2,r2) <-> \
L(r!1).R(r1!1,r2!3).L(r!2).R(r1!2,r2!3) k2, k_2 # Dimirization
R(r2!+,r3~Y) -> R(r2!+,r3~pY) k3 # Receptor phosphorylation at site r3
R(r3~pY) -> R(r3~Y) k_3 # Receptor dephosphorylation at site r3
R(r2!+,r4~Y) -> R(r2!+,r4~pY) k4 # Receptor phosphorylation at site r4
R(r4~pY) -> R(r4~Y) k_4 # Receptor dephosphorylation at site r4
R(r3~pY) + A(r) <-> R(r3~pY!1).A(r!1) k5, k_5 # Binding adapter A
R(r4~pY) + B(b1) <-> R(r4~pY!1).B(b1!1) k6, k_6 # Binding adapter B
B(b1!+,b2~Y) -> B(b1!+,b2~pY) k7 # Adaptor B phosphorylation at site b2
B(b2~pY) -> B(b2~Y) k_7 # Adaptor B dephosphorylation at site b2
B(b1!+,b3~Y) -> B(b1!+,b3~pY) k8 # Adaptor B phosphorylation at site b3
B(b3~pY) -> B(b3~Y) k_8 # Adaptor B dephosphorylation at site b3
end reaction_rules
begin observables
Molecules L_tot L
Molecules R_tot R
Molecules A_tot A
Molecules B_tot B
Molecules R_dim R.R
Molecules Abound A(r!+)
Molecules B1pY B(b2~pY)
Molecules B2pY B(b3~pY)
end observables
generate_network({overwrite=>1});
simulate_ode({t_end=>40,n_steps=>40,atol=>1e-8,rtol=>1e-8,sparse=>1});
[edit]
